String.slice()

Доступность

Flash Player 5.

Синтаксис

my_str.slice(start:Number, [end:Number]) : String

Параметры

start Число; указывающее индекс стартовой позиции промежутка.. Если start отрицательное число, стартовая позиция определяется с конца строки, где -1 последний символ.

end Число; целое равное 1+ индекс символа окончания промежутка. Символ с индексом равным параметру end не вставляется в извлекаемую строку. Если параметр опущен, используется String.length. Если end отрицательное число, конечная точка определяеться с конца строки, где -1 - последний символ.

Возвращает

Строка; подстрока указанной строки.

Описание

Метод; возвращает строку, начиная с символа start и все символы после него до, но не включая, символа end . Оригинальный объект String не изменяется. Если параметр end не определён, окончание подстроки совпадает с окончанием строки. Если символ индексированный как start совпадает с символом индексированным как end, метод возвращает пустую строку.

Пример

В следующем примере создается переменная my_str, имеющая строковое значение, затем происходит обращение к методу slice() с использованием различных значений для параметров start и end . Каждый вызов slice() сопровождается вызовом функции trace() для вывода выражения в Output панели.

// Значения мндексов для строковых литералов
// положительные индексы:  0   1   2   3   4
// строка:                 L   o   r   e   m
// отрицательные индексы: -5  -4  -3  -2  -1

var my_str:String = "Lorem";

// выборка первого символа
trace("slice(0,1): "+my_str.slice(0, 1)); // выводится: slice(0,1): L
trace("slice(-5,1): "+my_str.slice(-5, 1)); // выводится: slice(-5,1): L

// выборка следующих трёх символов
trace("slice(1,4): "+my_str.slice(1, 4)); // slice(1,4): ore
trace("slice(1,-1): "+my_str.slice(1, -1)); // slice(1,-1): ore

// выборки которые возвращают пустые строки, так как start 
//расположен не левее чем end
trace("slice(1,1): "+my_str.slice(1, 1)); // slice(1,1):
trace("slice(3,2): "+my_str.slice(3, 2)); // slice(3,2):
trace("slice(-2,2): "+my_str.slice(-2, 2)); // slice(-2,2):

// выборки где в качестве параметра end используется String.length, 
// которое эквивалентно 5
trace("slice(0): "+my_str.slice(0)); // slice(0): Lorem
trace("slice(3): "+my_str.slice(3)); // slice(3): em

Некоторые примеры есть также в файле Strings.fla папки HelpExamples . В списке даны примерные пути к этой папке :

Windows: \Program Files\Macromedia\Flash MX 2004\Samples\HelpExamples\
Macintosh: HD/Applications/Macromedia Flash MX 2004/Samples/HelpExamples/

См.также

String.substr(), String.substring()

Посмотреть комментарии LiveDocs

Предыдущая | Следующая | Оглавление